EXIT

Close the current batch script, exit the current subroutine or close the CMD.EXE session, optionally setting an errorlevel.

Syntax
      EXIT [/B] [exitCode]

Key
    /B        When used in a batch script, this option will exit 
              only the script (or subroutine) but not CMD.EXE
              If executed on the command-line it will close CMD.exe

   exitCode   Sets the %ERRORLEVEL% to a numeric number.
              If quitting CMD.EXE, sets the process exit code no.

To close an interactive command prompt, the keyboard shortcut ALT + F4 is an alternative to typing EXIT.

If you start a second nested CMD shell (or PowerShell), this will be added to the TITLE of the CMD/terminal window, when you EXIT back to the initial shell, the Title will also revert making it possible to track how many nested shells you have open.

Errorlevel

EXIT /b has the option to set a specific exit code, EXIT /b 0 for sucess, EXIT /b 1 (or greater) for an error.
The exit code can be an integer of up to 10 digits in length (positive or negative).

EXIT without an ExitCode acts the same as goto:eof and will not alter the ERRORLEVEL

n.b. You should never attempt to directly write to the %ERRORLEVEL% system variable, (SET ERRORLEVEL n ) instead use EXIT /b n as a safe way to set the internal ERRORLEVEL to n.

Ctrl-C

An errorlevel of -1073741510 will be interpreted by CMD.exe as a Ctrl-C Key sequence to cancel the current operation, not the entire script which EXIT will do.

To use this in a batch file, launch a new CMD session and immediately exit it, passing this errorlevel. The script will then act as though Ctrl-C had been pressed. Source and examples on DosTips.com.

::Ctrl-C
cmd /c exit -1073741510

When EXIT /b used with FOR /L, the execution of the commands in the loop is stopped, but the loop itself continues until the end count is reached. This will cause slow performance if the loop is (pointlessly) counting up to a large number.
In the case of an infinite loop, this EXIT /b behaviour will cause the script to hang until manually terminated with Ctrl + C

Exiting nested FOR loops, EXIT /b can be used to exit a FOR loop that is nested within another FOR loop.
This will only work if the inner FOR loop is contained in a separate subroutine, so that EXIT /b (or goto:eof) will terminate the subroutine.

Examples

Exit if a required file is missing:

@Echo Off
If not exist MyimportantFile.txt Exit /b
Echo If we get this far the file was found

Set the errorlevel to 5:

@Echo Off
Call :setError
Echo %errorlevel%
Goto :eof

:setError
Exit /B 5

Run a batch file which exits with an error and then display it. In these examples throw_err.cmd does nothing other than exit with error #3:

C:\> Echo @exit /b 3 > throw_err.cmd
C:\> CMD /c throw_err.cmd && echo Success || echo Error: %errorlevel%
1 C:\> CMD /K throw_err.cmd && echo Success || echo Error: %errorlevel% C:\> exit 3 C:\> Echo @exit 3 > throw_err.cmd C:\> CMD /c throw_err.cmd && echo Success || echo Error: %errorlevel%
3 From PowerShell (this works with or without /b): PS C:\> ./throw_err.cmd PS C:\> $lastExitCode 3

Use EXIT /b to exit a nested FOR loop (so skipping the values X,Y and Z), but still continue back to the main outer loop:

@Echo Off
Setlocal 
For %%A in (alpha beta gamma) DO (
   Echo Outer loop %%A
   Call :inner 
)
Goto :eof

:inner
For %%B in (U V W X Y Z) DO (
   if %%B==X ( exit /b 2 )
   Echo    Inner loop    Outer=%%A Inner=%%B
)

EXIT is an internal command.
If Command Extensions are disabled, the EXIT command will still work but may output a spurious 'cannot find the batch label' error.

“Making music is not about a place you go. It’s about a place you get out of. I’m underwater most of the time, and music is like a tube to the surface that I can breathe through. It’s my air hole up to the world. If I didn’t have the music I’d be under water, dead” ~ Fiona Apple

Related commands

VERIFY - Provides an alternative method of raising an error level without exiting.
TSKILL - End a running process.
Equivalent PowerShell: Exit - Exit PowerShell or break - Exit a program loop.
Equivalent bash command (Linux): break - Exit from a loop.


 
Copyright © 1999-2024 SS64.com
Some rights reserved